Alle Windows-Kommandos

Liste der Windows-Kommandozeilentools - Kommandos und -Befehle unter MS Windows

Liste der Windows-eigenen Kommandos

color

Übersicht

Befehl
Kurzbeschreibung
Syntax
Beispiele
     Status des cmd-Fensters mit Farbe und Titel kennzeichnen
     net start: einzelnen Dienst prüfen und ggf. starten


Befehlcolor
KurzbeschreibungLegt die Hinter- und Vordergrundfarben für die Konsole fest.
Syntax
Hinweis: Dies ist ein internes Kommando. 
Kommando zum Anzeigen der Hilfe: color /? 

Legt die Hinter- und Vordergrundfarben für die Konsole fest.

COLOR [attr]

  attr      Gibt die Farbattribute für die Konsolenausgabe an.

Farbattribute werden durch ZWEI hexadezimale Ziffern angegeben - die erste
bezieht sich auf den Hintergrund, die zweite auf den Vordergrund. Jede Ziffer
kann einen der folgenden Werte annehmen:

    0 = Schwarz        8 = Dunkelgrau
    1 = Dunkelblau     9 = Blau
    2 = Dunkelgrün     A = Grün
    3 = Blaugrün       B = Zyan
    4 = Dunkelrot      C = Rot
    5 = Lila        D = Magenta
    6 = Ocker          E = Gelb
    7 = Hellgrau       F = Weiß

Wenn der COLOR-Befehl ohne Argument aufgerufen wird, werden die Farbein-
stellungen wiederhergestellt, mit denen CMD.EXE gestartet wurde. Diese werden
durch das aktuelle Konsolenfenster, die /T-Befehlszeilenoption oder durch den
Registrierungswert "DefaultColor" bestimmt.

Der COLOR-Befehl legt den ERRORLEVEL mit 1 fest, wenn versucht wird,
diesen Befehl mit einer Vordergrundfarbe auszuführen, die mit der Hinter-
Grundfarbe identisch ist.

Beispiel: "COLOR fc" erzeugt Rot auf weißem Hintergrund.
Beispiele

Status des cmd-Fensters mit Farbe und Titel kennzeichnen

Den Status der Arbeitsgänge kann man mit Hilfe von Bildschirmfarben kennzeichnen, z.B.
  • schwarzer Hintergrund und dunkelgraue Schrift, wenn ein Prozess arbeitet
  • blauer Hintergrund und weisse Schrift, wenn eine Benutzerinteraktion erwartet wird
  • zum Abschluss: grüner Hintergrund = OK oder roter Hintergrund= Fehler
Gerade, wenn ein Prozess länger dauert (Defragmentieren der Festplatte oder ein längeres Backup), braucht man nicht immer ein geöffnetes cmd-Fenster. Mit Hilfe des Title-Kommandos kann vor Start einer Aktion der Titelzeile ein (hilfreicher) Text eingeblendet werden. Dann sieht man selbst bei verkleinertem cmd-Fenster in der Taskleiste, was gerade im Skript passiert.

Das nachfolgende Beispiel-Skript durchsucht rekursiv die Laufwerke (entspr. Variable sDrive) nach Dateien und/ oder Ordnern nach einem regulären Ausdruck im Ordner- und Dateinamen.

@echo off
rem ------------------------------------------------------------
::	CONFIG
rem ------------------------------------------------------------

	set scriptname=Dateisuche

	:: zu durcsuchende Laufwerke
	set sDrives=C D E

	:: Farben
	set colWork=color 08
	set colWait=color 17

rem ------------------------------------------------------------
::	MAIN
rem ------------------------------------------------------------

	%colWork%
	title %scriptname%
	echo xxxxx ORDNER/ DATEI-SUCHE xxxxx
	echo Dieses Skript sucht auf den Laufwerken %sDrives%
	echo Ordner und Dateinamen nach einem angegebenen Muster (Regex moeglich).
	%colWait%
	set /p dmuster=Dateimuster eingeben: 
	if "%dmuster%"=="" exit
	%colWork%
	for %%d in (%sDrives%) do (
		title %scriptname% - durchsuche %%d nach %dmuster% ...
		dir /s /b %%d:\ | findstr "%dmuster%"
	)
	echo fertig.
	title %scriptname% - fertig.
	%colWait%
	pause && exit 

rem ------------------------------------------------------------

s.a. » dir » exit » for » if » pause » set » title

net start: einzelnen Dienst prüfen und ggf. starten

Der einfache Aufruf von
net start
listet alle laufenden Services auf. Mit finstr kann man in dieser Ausgabe nach dem Namen des zu prüfenden Dienstes suchen. Wird der Dienst gefunden, färbt sich der Bildschirm grün. Wenn nicht, wird der Bildschirm rot gefärbt und versucht, diesen Dienst zu starten. Anschliessend erfolgt ein erneuter Test, ob der Start erfolgreich war.
Alle Fehler werden in einer Log-Datei festgehalten.

Hinweis:
Zum Starten des Dienstes sind Administrator-Rechte erforderlich.

Wenn man gezielt einen bestimmten Dienst am Laufen halte will, kann man nachfolgendes Batch-Skript in den Taskplaner alle n Minuten einbinden.

@echo off
set "myservice=ipMonitor"
set "errorlog=%~dp0\%myservice%_errorlog.txt"

echo.
echo ===== Service Checker =====
echo.

title teste %myservice%
echo suche in aktiven Services nach %myservice% ...
net start | findstr /c:"%myservice%" && (
        title OK: %myservice%
        echo OK, Service laeuft.
        color 2f
        goto end
)
title starte %myservice%
color 4f
echo FEHLER: Service [%myservice%] laeuft nicht - versuche ihn zu starten
echo %date% %time%: FEHLER: Service [%myservice%] laeuft nicht - versuche ihn zu starten >>"%errorlog%"

net start "%myservice%" && (
        title OK: %myservice%
        echo %date% %time%: OK, nun gestartet >>"%errorlog%"
        echo Service wurde gestartet. Na, immerhin.
        goto end
)
color cf
echo FEHLER: Service konnte nicht gestartet werden.
echo %date% %time%: FEHLER: Service konnte nicht gestartet werden. >>"%errorlog%"
goto end 


:end
echo.
echo fertig. Schliesse in 5 sek.
ping -n 6 localhost >nul

s.a. » net start


Übersicht