Alle Windows-Kommandos

Liste der Windows-Kommandozeilentools - Kommandos und -Befehle unter MS Windows

Liste der Windows-eigenen Kommandos

net start

Übersicht

Befehl
Kurzbeschreibung
Syntax
Beispiele
     net start: einzelnen Dienst prüfen und ggf. starten
     VMWare-Services starten und stoppen


Befehlnet start
KurzbeschreibungNET START listet aktive Dienste auf oder startet einen Dienst
Syntax
 
Kommando zum Anzeigen der Hilfe: net help start 

Die Syntax dieses Befehls lautet:


NET START 
[Dienst]

NET START listet aktive Dienste auf.

Dienst    Kann die folgenden Dienste enthalten:
          Ablagemappendienst:                  CLIPBOOK
          Anmeldedienst:                       NETLOGON
          Arbeitsstationsdienst:               WORKSTATION
          Client Service für NetWare:          NTCWORKSTATION
          Computerbrowser:                     BROWSER 
          Ereignisprotokoll:                   EVENTLOG
          Dateireplikation:                    NTFRS
          DHCP-Client:                         DHCP
          Nachrichtendienst:                   MESSENGER
          NT-LM-Sicherheitsdienst:             NTLMSSP
          Plug & Play:                         SERVICES
          RAS-Verbindungs-Manager:             RASMAN
          Remoteprozeduraufruf (RPC) Locator:  RPCLOCATOR
          Remoteprozeduraufruf (RPC)-Dienst:   RPCSS
          Routing und RAS:                     REMOTEACCESS
          Serverdienst:                        SERVER
          Spooler:                             SPOOLER
          TCP/IP-NetBIOS-Hilfsprogramm:        LMHOSTS
          USV-Dienst:                          UPS
          Warndienst:                          ALERTER
          Zeitplan:                            SCHEDULE
                                             
Bei der Eingabe an der Befehlszeile müssen Dienstnamen, die aus zwei oder mehr
Worten bestehen, in Anführungszeichen eingeschlossen werden, z. B. startet
NET START "Plug & Play" den Plug & Play-Dienst.

NET START kann auch Dienste starten, die nicht von Windows
zur Verfügung gestellt werden.

NET HELP Befehl | MORE zeigt die Hilfe seitenweise an.


--- Hinweis --- 
Diese Seite wurde automatisch erzeugt und muss ggf. noch nachbearbeitet werden.
Beispiele

net start: einzelnen Dienst prüfen und ggf. starten

Der einfache Aufruf von
net start
listet alle laufenden Services auf. Mit finstr kann man in dieser Ausgabe nach dem Namen des zu prüfenden Dienstes suchen. Wird der Dienst gefunden, färbt sich der Bildschirm grün. Wenn nicht, wird der Bildschirm rot gefärbt und versucht, diesen Dienst zu starten. Anschliessend erfolgt ein erneuter Test, ob der Start erfolgreich war.
Alle Fehler werden in einer Log-Datei festgehalten.

Hinweis:
Zum Starten des Dienstes sind Administrator-Rechte erforderlich.

Wenn man gezielt einen bestimmten Dienst am Laufen halte will, kann man nachfolgendes Batch-Skript in den Taskplaner alle n Minuten einbinden.

@echo off
set "myservice=ipMonitor"
set "errorlog=%~dp0\%myservice%_errorlog.txt"

echo.
echo ===== Service Checker =====
echo.

title teste %myservice%
echo suche in aktiven Services nach %myservice% ...
net start | findstr /c:"%myservice%" && (
        title OK: %myservice%
        echo OK, Service laeuft.
        color 2f
        goto end
)
title starte %myservice%
color 4f
echo FEHLER: Service [%myservice%] laeuft nicht - versuche ihn zu starten
echo %date% %time%: FEHLER: Service [%myservice%] laeuft nicht - versuche ihn zu starten >>"%errorlog%"

net start "%myservice%" && (
        title OK: %myservice%
        echo %date% %time%: OK, nun gestartet >>"%errorlog%"
        echo Service wurde gestartet. Na, immerhin.
        goto end
)
color cf
echo FEHLER: Service konnte nicht gestartet werden.
echo %date% %time%: FEHLER: Service konnte nicht gestartet werden. >>"%errorlog%"
goto end 


:end
echo.
echo fertig. Schliesse in 5 sek.
ping -n 6 localhost >nul

s.a. » color

VMWare-Services starten und stoppen

Für VMWare Workstation oder den VMWare Player gibt es eine Reihe von Diensten, die man nicht permanent braucht. Eben nur dann, wenn man mit dem entspr. Tool arbeiten möchte.

Nachfolgend eine Batchdatei, die eine handvoll Dienst für VMware prüft. Wenn die Services alle nicht laufen, werden sie nach Tastendruck gestartet. Und auch umgekehrt: wenn sie alle laufen, werden sie nach Tastendruck angehalten.

Das Starten und Stoppen von Diensten erfordert Administrator-Rechte.

Funktionsweise:
  • Zeile 30 holt bei Aufruf des Skripts den aktuellen Status - in :getStatus (Zeile 45) werden die laufenden Dienste ausgewertet
    • Zeile 49: Die Ausgabe von net start wird in eine tempöräre Datei geschrieben und enthält alle laufenden Dienste
    • In der Textdatei werden in einem For-Loop (Zeile 50) alle zu prüfenden Dienste mit findstr /c:[Text] gesucht (Zeile 56). Treffer und Nicht-Treffer werden in je einer Statusvariable (OneStopped, OneRunning) festgehalten. Der Status jedes unserer Dienste wird angezeigt.
  • Zeile 32: Wenn alle Dienste gestartet sind, werden sie in :startServices (Zeile 61) gestartet.
  • Zeile 33: Wenn alle Dienste gestoppt sind, werden sie in :startServices (Zeile 73) gestoppt.
@echo off
rem ======================================================================
::
::  VMWARE Service Switcher
::
rem ----------------------------------------------------------------------
::  2007-05-18  v1.0  axel hahn
rem ======================================================================


rem ----------------------------------------------------------------------
::	CONFIG
rem ----------------------------------------------------------------------
set lServices=
set lServices=%lServices% "VMware Authorization Service"
set lServices=%lServices% "VMware DHCP Service"
set lServices=%lServices% "VMware NAT Service"
set lServices=%lServices% "VMware Virtual Mount Manager Extended"

set tmpfile=%temp%\services_.tmp


rem ----------------------------------------------------------------------
:: MAIN
rem ----------------------------------------------------------------------
color 08
echo.
echo ===== VMWARE SERVICE SWITCHER =====
echo.
call :getStatus
rem echo OneStopped - %OneStopped% .. OneRunning - %OneRunning%
if "%OneStopped%"=="N" goto stopServices
if "%OneRunning%"=="N" goto startServices
echo.
color cf
echo.
echo --- CONFUSION:
echo some services are running - some dont.
echo.
goto end

rem ----------------------------------------------------------------------
::  SUBS
rem ----------------------------------------------------------------------
:getStatus
set OneStopped=N
set OneRunning=N
echo reading service state ...
net start >"%tmpfile%"
for %%a in (%lServices%) do call :checkService %%a
del "%tmpfile%"
echo.
goto end2 

:checkService
findstr /c:%1 "%tmpfile%" >nul && ( echo YES: %1 is running && set OneRunning=Y && goto end2)
echo NO: %1 is stopped && set OneStopped=Y
goto end2


:startServices
color 27
echo --- need to START services
pause
for %%a in (%lServices%) do (
	echo ... starting %%a ...
	net start %%a
)
call :getStatus
goto end


:stopServices
color 17
echo --- need to STOP services
pause
for %%a in (%lServices%) do (
	echo ... stopping %%a ...
	net stop %%a
)
call :getStatus
goto end


rem ----------------------------------------------------------------------
::  END
rem ----------------------------------------------------------------------

:end 
echo --- done
pause

:end2

rem ----------------------------------------------------------------------
::  EOF
rem ----------------------------------------------------------------------

s.a. » net stop » call » for


Übersicht